Delphi component to animate the display / hide of controls at runtime

Question

In Delphi, I show / hide the controls at runtime, and it doesn’t look so good as the controls suddenly appear or disappear, so does anyone know a component that can show / hide (using a visible property), but with some kind of animation?

thank

Answer 1

Let it go AnimateWindow . For WinControls only, well, in any case, this does not look amazing:

procedure TForm1.Button1Click(Sender: TObject);
begin
  if Button2.Visible then
    AnimateWindow(Button2.Handle, 250, AW_HIDE or AW_VER_NEGATIVE or AW_SLIDE)
  else
    AnimateWindow(Button2.Handle, 250, AW_VER_POSITIVE or AW_SLIDE);
  Button2.Visible := not Button2.Visible; // synch with VCL
end;

the edit: . In the streaming version, to hide the simultaneous display of several controls:

type
  TForm1 = class(TForm)
    ..
  private
    procedure AnimateControls(Show: Boolean; Controls: array of TWinControl);
    procedure OnAnimateEnd(Sender: TObject);
  public
  end;

implementation
  ..

type
  TAnimateThr = class(TThread)
  protected
    procedure Execute; override;
  public
    FHWnd: HWND;
    FShow: Boolean;
    constructor Create(Handle: HWND; Show: Boolean);
  end;

{ TAnimateThr }

constructor TAnimateThr.Create(Handle: HWND; Show: Boolean);
begin
  FHWnd := Handle;
  FShow := Show;
  FreeOnTerminate := True;
  inherited Create(True);
end;

procedure TAnimateThr.Execute;
begin
  if FShow then 
    AnimateWindow(FHWnd, 250, AW_VER_POSITIVE or AW_SLIDE)
  else 
    AnimateWindow(FHWnd, 250, AW_HIDE or AW_VER_NEGATIVE or AW_SLIDE);
end;

{ Form1 }

procedure TForm1.OnAnimateEnd(Sender: TObject);
begin
  FindControl(TAnimateThr(Sender).FHWnd).Visible := TAnimateThr(Sender).FShow;
end;

procedure TForm1.AnimateControls(Show: Boolean; Controls: array of TWinControl);
var
  i: Integer;
begin
  for i := Low(Controls) to High(Controls) do
    with TAnimateThr.Create(Controls[i].Handle, Show) do begin
      OnTerminate := OnAnimateEnd;
      Resume;
    end;
end;


procedure TForm1.Button5Click(Sender: TObject);
begin
  AnimateControls(not Button1.Visible,
      [Button1, Button2, Button3, Edit1, CheckBox1]);
end;