Return all months and years between a date range - SQL

Question

I am a little puzzled by how I can do this.

I have a very simple query that currently returns sales for each product by year and month. It is grouped by year / month and summarizes the quantity. This returns one row for each product / year / month combo where the sale was.

If there was no sale within a month, then there is no data.

I would like my query to return one row of data for each product for each year / month in my date range, regardless of whether there was an order.

If there is no order, then I can return 0 for this product / year / month.

Below is an example of my example.

Declare @DateFrom datetime, @DateTo Datetime
Set @DateFrom = '2012-01-01'
set @DateTo = '2013-12-31'

select 
Convert(CHAR(4),order_header.oh_datetime,120) + '/' + Convert(CHAR(2),order_header.oh_datetime,110) As YearMonth,
variant_detail.vad_variant_code,
sum(order_line_item.oli_qty_required) as 'TotalQty'

From 
variant_Detail
join order_line_item on order_line_item.oli_vad_id = variant_detail.vad_id
join order_header on order_header.oh_id = order_line_item.oli_oh_id

Where 
(order_header.oh_datetime between @DateFrom and @DateTo)

Group By 
Convert(CHAR(4),order_header.oh_datetime,120) + '/' + Convert(CHAR(2),order_header.oh_datetime,110),
variant_detail.vad_variant_code

Answer 1

.

, .

Declare @DateFrom datetime, @DateTo Datetime
Set @DateFrom = '2012-01-01'
set @DateTo = '2013-12-31'

select 
YearMonthTbl.YearMonth,
orders.vad_variant_code,
orders.qty

From 
(SELECT  Convert(CHAR(4),DATEADD(MONTH, x.number, @DateFrom),120) + '/' + Convert(CHAR(2),DATEADD(MONTH, x.number, @DateFrom),110) As YearMonth
FROM    master.dbo.spt_values x
WHERE   x.type = 'P'        
AND     x.number <= DATEDIFF(MONTH, @DateFrom, @DateTo)) YearMonthTbl


left join 
    (select variant_Detail.vad_variant_code, 
    sum(order_line_item.oli_qty_required) as 'Qty', 
    Convert(CHAR(4),order_header.oh_datetime,120) + '/' + Convert(CHAR(2),order_header.oh_datetime,110) As 'YearMonth'
    FROM order_line_item 
    join variant_detail on variant_detail.vad_id = order_line_item.oli_vad_id
    join order_header on order_header.oh_id = order_line_item.oli_oh_id
    Where 
    (order_header.oh_datetime between @DateFrom and @DateTo)
    GROUP BY variant_Detail.vad_variant_code,
    Convert(CHAR(4),order_header.oh_datetime,120) + '/' + Convert(CHAR(2),order_header.oh_datetime,110)
    ) as Orders on Orders.YearMonth = YearMonthTbl.YearMonth

Answer 2

CTE. : http://blog.lysender.com/2010/11/sql-server-generating-date-range-with-cte/

:

WITH CTE AS
(
    SELECT @start_date AS cte_start_date
    UNION ALL
    SELECT DATEADD(MONTH, 1, cte_start_date)
    FROM CTE
    WHERE DATEADD(MONTH, 1, cte_start_date) <= @end_date   
)
SELECT * 
FROM CTE

Answer 3

This is what I put together. Of course, debugging will be required, but I think it will lead you in the right direction. I broke requests into different parts to try to simplify reading. Hope this helps.

DECLARE @dateFrom DATETIME, @dateTo DATETIME

SELECT @dateFrom = MIN(oh_datetime) FROM order_header
SELECT @dateTo = MAX(oh_datetime) FROM order_header

;WITH
y AS
(
    SELECT YEAR(@dateFrom) AS [Year]
    UNION ALL
    SELECT [Year] + 1
    FROM y
    WHERE
          [Year] < YEAR (GETDATE())
),
m AS
(
    SELECT 1 AS [Month]
    UNION ALL
    SELECT [Month] + 1
    FROM m
    WHERE
          [Month] < 12
),
dates AS
(
SELECT
    CAST(y.[Year] AS nvarchar(4)) + N'/' + RIGHT(N'00' + CAST(m.[Month] AS nvarchar(2)), 2) AS YearMonth
FROM
    y CROSS JOIN m
),
qty AS
(
SELECT
    YEAR(oh.oh_datetime) + N'/' + MONTH(oh.oh_datetime) AS YearMonth,
    v.vad_variant_code,
    oli.oli_qty_required AS Qty
FROM
    variant_Detail AS v
        INNER JOIN order_line_item AS oli ON oil.oli_vad_id = v.vad_id
        INNER JOIN order_header AS oh ON oh.oh_id = oli.oli_oh_id
)
SELECT
    d.YearMonth,
    qty.vad_variant_code,
    SUM(qty.Qty) AS TotalQty
FROM
    dates AS d LEFT OUTER JOIN qty
        ON d.YearMonth = qty.YearMonth
GROUP BY
    d.YearMonth,
    qty.vad_variant_code