Geek Answers Handbook

Vbscript kill processes

I am trying to kill all instances of a process called "AetherBS.exe", but the following VBscript does not work. I'm not quite sure where / why this does not work.

So, how can I kill the whole process "AetherBS.exe?"

CloseAPP "AetherBS.exe"

Function CloseAPP(Appname)
    strComputer = "."
    Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    Set colItems = objWMIService.ExecQuery( _
        "SELECT * FROM Win32_Process", , 48)
    For Each objItem In colItems
        If InStr(1,Ucase(objItem.Name),Appname) >= 1 Then
            objItem.Terminate
        End If
    Next
End Function
0
source share
3 answers

The problem is the following line:

If InStr(1,Ucase(objItem.Name),Appname) >= 1 Then

Here you convert the property value Win32_Process.Nameto uppercase, but not convert Appnameto uppercase. By default, it InStrperforms case-sensitive searches, so if the input lines are the same but different from each other, you won’t get a match.

, Appname :

If InStr(1, UCase(objItem.Name), UCase(Appname)) >= 1 Then

vbTextCompare, :

If InStr(1, objItem.Name, Appname, vbTextCompare) >= 1 Then


, :

Set colItems = objWMIService.ExecQuery( _
    "SELECT * FROM Win32_Process WHERE Name='" & Appname & "'", , 48)
+3

, :

Sub KillProc( myProcess )
'Authors: Denis St-Pierre and Rob van der Woude
'Purpose: Kills a process and waits until it is truly dead

    Dim blnRunning, colProcesses, objProcess
    blnRunning = False

    Set colProcesses = GetObject( _
                       "winmgmts:{impersonationLevel=impersonate}" _
                       ).ExecQuery( "Select * From Win32_Process", , 48 )
    For Each objProcess in colProcesses
        If LCase( myProcess ) = LCase( objProcess.Name ) Then
            ' Confirm that the process was actually running
            blnRunning = True
            ' Get exact case for the actual process name
            myProcess  = objProcess.Name
            ' Kill all instances of the process
            objProcess.Terminate()
        End If
    Next

    If blnRunning Then
        ' Wait and make sure the process is terminated.
        ' Routine written by Denis St-Pierre.
        Do Until Not blnRunning
            Set colProcesses = GetObject( _
                               "winmgmts:{impersonationLevel=impersonate}" _
                               ).ExecQuery( "Select * From Win32_Process Where Name = '" _
                             & myProcess & "'" )
            WScript.Sleep 100 'Wait for 100 MilliSeconds
            If colProcesses.Count = 0 Then 'If no more processes are running, exit loop
                blnRunning = False
            End If
        Loop
        ' Display a message
        WScript.Echo myProcess & " was terminated"
    Else
        WScript.Echo "Process """ & myProcess & """ not found"
    End If
End Sub

:

KillProc "AetherBS.exe"
+8

script

wmic path win32_process Where "Caption Like '%%AetherBS.exe%%'" Call Terminate

cmd

wmic path win32_process Where "Caption Like '%AetherBS.exe%'" Call Terminate
-1

More articles:


All Articles