Perl - reading a file line by line in reverse

Question

Possible duplicate:
How to read lines from the end of a file in Perl?

First read the last line, and then the last, but one, etc. The file is too large to fit in memory.

Answer 1

Reading lines in reverse order:

use File::ReadBackwards;

my $back = File::ReadBackwards->new(shift @ARGV) or die $!;
print while defined( $_ = $back->readline );

At first, I misunderstood the question and thought that you want to read back and forth in alternating fashion , which seems more interesting. :)

use strict;
use warnings;
use File::ReadBackwards ;

sub read_forward_and_backward {
    # Takes a file name and a true/false value.
    # If true, the first line returned will be from end of file.
    my ($file_name, $read_from_tail) = @_;

    # Get our file handles.
    my $back = File::ReadBackwards->new($file_name) or die $!;
    open my $forw, '<', $file_name or die $!;

    # Return an iterator.
    my $line;    
    return sub {
        return if $back->tell <= tell($forw);
        $line = $read_from_tail ? $back->readline : <$forw>;
        $read_from_tail = not $read_from_tail;
        return $line;
    }

}

# Usage.    
my $iter = read_forward_and_backward(@ARGV);
print while defined( $_ = $iter->() );

Answer 2

Simple, if tacavailable:

#! /usr/bin/perl

use warnings;
no warnings 'exec';
use strict;

open my $fh, "-|", "tac", @ARGV
  or die "$0: spawn tac failed: $!";

print while <$fh>;

Run:

$ ./readrev readrev
print while <$ fh>;

  or die "$ 0: spawn tac failed: $!";
open my $ fh, "- |", "tac", @ARGV

use strict;
no warnings 'exec';
use warnings;

#! /usr/bin/perl

Answer 3

I have been using PerlIO::reversefor this recently. I prefer the IO layer PerlIO::reverseover the user object or associated descriptor interface offered File::ReadBackwards.