Geek Answers Handbook

Variable increase in xslt 2.0 without use for each

I have xml (below) in which If a node (ref_name_1, ref_name_2, ref_name_3) contains some text, we will generate the corresponding node using xslt and assign the id number, for example, 1, 2, etc. in the attribute. I tried to find a solution, but did not find anything suitable for this, not even in stackoverflow, so a little help would be very noticeable.

XML example

<?xml version="1.0" encoding="UTF-8"?>
<reference>
   <ref_name_1>reference1</ref_name_1>
   <ref_company_1>company1</ref_company_1>
   <ref_position_1>position3</ref_position_1>
   <ref_name_2 />
   <ref_company_2>company2</ref_company_2>
   <ref_position_2>position2</ref_position_2>
   <ref_name_3>reference3</ref_name_3>
   <ref_company_3>company3</ref_company_3>
   <ref_position_3>position3</ref_position_3>
</reference>

Expected Result:

<?xml version="1.0" encoding="UTF-8"?>
<services>
   <service name="reference" id="1">
      <name>reference1</name>
      <company>company1</company>
      <position>position1</position>
   </service>
   <service name="reference" id="2">
      <name>reference3</name>
      <company>company3</company>
      <position>position3</position>
   </service>
</services>
+4
source share
2 answers

The key is a function position(). It works as with <xsl:for-each>:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output indent="yes"/>  

  <xsl:template match="/reference">
    <services>
      <xsl:for-each select="*[starts-with(local-name(), 'ref_name_')][. != '']">
        <xsl:variable name="originalNumber" select="substring-after(local-name(), 'ref_name_')"/>

        <service name="reference" id="{position()}">
          <name>
            <xsl:value-of select="."/>
          </name>
          <company>
            <xsl:value-of select="following-sibling::*[local-name()=concat('ref_company_', $originalNumber)][1]"/>
          </company>
          <position>
            <xsl:value-of select="following-sibling::*[local-name()=concat('ref_position_', $originalNumber)][1]"/>
          </position>
        </service>
      </xsl:for-each>
    </services>
  </xsl:template>

</xsl:stylesheet>

As with <xsl:apply-tempaltes>:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:output indent="yes"/>  

  <xsl:template match="/reference">
    <services>
      <xsl:apply-templates select="*[starts-with(local-name(), 'ref_name_')][. != '']"/>
    </services>
  </xsl:template>


  <xsl:template match="*[starts-with(local-name(), 'ref_name_')][. != '']">
    <xsl:variable name="originalNumber" select="substring-after(local-name(), 'ref_name_')"/>

    <service name="reference" id="{position()}">
      <name>
        <xsl:value-of select="."/>
      </name>
      <company>
        <xsl:value-of select="following-sibling::*[local-name()=concat('ref_company_', $originalNumber)][1]"/>
      </company>
      <position>
        <xsl:value-of select="following-sibling::*[local-name()=concat('ref_position_', $originalNumber)][1]"/>
      </position>
    </service>  </xsl:template>

</xsl:stylesheet>
+3
source

xsl:number, for-each-group group-starting-with:

<xsl:transform xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

    <xsl:output indent="yes"/>

    <xsl:template match="reference">
        <services>
            <xsl:for-each-group select="*" group-starting-with="*[starts-with(local-name(), 'ref_name_')]">
                <xsl:if test="normalize-space()">
                    <service name="reference">
                        <xsl:attribute name="id">
                            <xsl:number count="*[starts-with(local-name(), 'ref_name_') and normalize-space()]"/>
                        </xsl:attribute>
                        <xsl:apply-templates select="current-group()"/>
                    </service>
                </xsl:if>
            </xsl:for-each-group>
        </services>
    </xsl:template>

    <xsl:template match="reference/*">
        <xsl:element name="{replace(local-name(), '^ref_|_[0-9]+$', '')}">
            <xsl:value-of select="."/>
        </xsl:element>
    </xsl:template>

</xsl:transform>

http://xsltransform.net/ncdD7nm.

+1

More articles:


All Articles