Create a sequence based on the previous value

Question

I am learning F # (second day O :-)), and I want to create a Collatz sequence where each value is calculated based on Previous. I know ho do it in C #

public static void Main(string[] args)
{
    Console.WriteLine(string.Join(", ", collatz(13)));
}

static IEnumerable<int> collatz(int n)
{
    while (n != 1)
    {
        yield return n;

        if (n % 2 == 0)
            n /= 2;
        else
            n = 3 * n + 1;
    }

    yield return 1;
}

or how to create such an array in F #

let rec collatz = function
    | 1 -> [ 1 ]
    | n when n % 2 = 0 -> n::collatz (n / 2)
    | n -> n::collatz (3 * n + 1)

collatz 13 |> Seq.map string |> String.concat ", " |> printfn "%s"

but don’t figure out the solution to the sequence ...

Answer 1

You can use a sequence expression:

let rec collatzSeq n = seq {
    match n with
    | 1 -> yield 1
    | n when n % 2 = 0 ->
        yield n
        yield! collatzSeq (n / 2)
    | n ->
        yield n
        yield! collatzSeq (3 * n + 1)
}

Answer 2

You can do this quite briefly using Seq.unfold...

let collatzSeq = Seq.unfold <| function 
    | 1 -> Some(1, -1) 
    | -1 -> None 
    | n when n % 2 = 0 -> Some(n, n / 2) 
    | n -> Some(n, 3 * n + 1)

Answer 3

, , , :

type CollatzState = 
    |Continue of int
    |Stop

let collatz v =
    let unfolder =
        function
        |Stop -> None
        |Continue 1 -> Some (1, Stop)
        |Continue n when n % 2 = 0 -> Some(n, Continue <| n/2)
        |Continue n -> Some (n, Continue <| 3*n+1)
    Seq.unfold (unfolder) (Continue v)

Seq.unfold , 1, .

CollatzState Option , , , .

Answer 4

let collatz n =
    let nr = ref n
    seq{
        while (!nr > 1) do
            yield !nr
            if !nr % 2 = 0 then 
                nr := !nr / 2 
            else 
                nr := 3 * !nr + 1 }
collatz 13
// val it : seq<int> = seq [13; 40; 20; 10; ...]

# ; ref . , .

memoisation. , .

let memoRec f =
    let d = new System.Collections.Generic.Dictionary<_,_>()
    let rec g x =
        match d.TryGetValue x with
        | true, res -> res
        | _ -> let res = f g x in d.Add(x, res); res
    g

let collatzRec =
    memoRec (fun f n -> seq{
        if n <= 1 then
            yield 1
        else
            yield n
            if n % 2 = 0 then yield! f (n / 2)
            else yield! f (3 * n + 1) } )