Graphical presentation of lists

Question

Say I have three lists: a={1,5,10,15} b={2,4,6,8} and c={1,1,0,1,0} . I need a graph that has a as the x axis, b as the y axis, and the red / black dot is 1/0. For. for example, Coordinate (5,4) will have a red dot.
In other words, the coordinate (a[i],b[i]) will have a red / black dot depending on whether c[i] 1 or 0.
I tried my hand with ListPlot , but cannot determine the options.

Answer 1

I suggest this.

 a = {1, 5, 10, 15}; b = {2, 4, 6, 8}; c = {1, 1, 0, 1}; Graphics[ {#, Point@ {##2}} & @@@ Thread@ {c /. {1 -> Red, 0 -> Black}, a, b}, Axes -> True, AxesOrigin -> 0 ] 

Or shorter but more confusing

 Graphics[ {Hue[1, 1, #], Point@ {##2}} & @@@ Thread@ {c, a, b}, Axes -> True, AxesOrigin -> 0 ] 

Answer 2

Leonid’s idea is perhaps more naive.

 f[a_, b_, c_] := ListPlot[Pick[Transpose[{a, b}], c, #] & /@ {0, 1}, PlotStyle -> {PointSize[Large], {Blue, Red}}] f[a, b, c] 

Edit: just for fun

 f[h_, a_, b_, c_, opt___] := h[Pick[Transpose[{a, b}], c, #] & /@ {0, 1}, PlotStyle -> {PointSize[Large], {Blue, Red}}, opt] f[ ListPlot, Sort@RandomReal [1, 100], Sin[(2 \[Pi] #)/100] + RandomReal[#/100] & /@ Range[100], RandomInteger[1, 100], Joined -> True, InterpolationOrder -> 2, Filling -> Axis] 

Answer 3

Here are your questions:

 a = {1, 5, 10, 15}; b = {2, 4, 6, 8}; c = {1, 1, 0, 1}; 

(I removed the last element from c to make it the same length as a and b ). I suggest separately making images for points with zeros and ones, and then combining them - this seems to be the easiest in this situation:

 showPoints[a_, b_, c_] := With[{coords = Transpose[{a, b}]}, With[{plotF = ListPlot[Pick[coords, c, #], PlotMarkers -> Automatic, PlotStyle -> #2] &}, Show[MapThread[plotF, {{0, 1}, {Black, Red}}]]]] 

Here is the usage:

 showPoints[a, b, c] 

Answer 4

One possibility:

 ListPlot[List /@ Transpose[{a, b}], PlotMarkers -> {1, 1, 0, 1} /. {1 -> { Style[\[FilledCircle], Red], 10}, 0 -> { { Style[\[FilledCircle], Black], 10}}}, AxesOrigin -> {0, 0}] 

As a conclusion:

Answer 5

You can get similar results (e.g. with Leonid) using Graphics:

  Graphics[{PointSize[.02], Transpose[{(c/. {1 -> Red, 0 -> Black}), Point /@ Transpose[{a, b}]}]}, Axes -> True, AxesOrigin -> {0, 0}]